Claude Code

安装

Claude Code 不是大模型本身，而是一个 AI 编程代理系统（Agent System），负责读取/修改本地项目、执行终端命令、和模型通信等；它本质是一个通用 Agent Runtime，默认调用 Anthropic 的 Claude 模型，但也支持接入其它厂商模型。

• 安装 & 更新

  以 Windows 为例，其它系统参考官网

  安装

  # 方式一，推荐使用 WinGet 安装，它从微软 WinGet 仓库获取软件清单，一般不会出错
  winget install Anthropic.ClaudeCode
  
  # 方式二，使用 irm 安装，这种方式对 VPN 更加严格，会从 Anthropic 服务器实时下载并执行安装脚本，可能会安装失败
  irm https://claude.ai/install.ps1 | iex

  更新

  # 执行如下指令更新即可
  claude update
  
  # 如果使用 WinGet 安装，执行如下指令更新
  winget upgrade Anthropic.ClaudeCode

集成 Opus 模型

• 介绍

  Claude 是 Anthropic 公司的大模型品牌，Opus / Sonnet / Haiku 是不同能力档位的具体模型，其中 Opus 最强。安装 Claude Code 后，购买官网订阅，在 Claude Code 中完成登录，即可在本地使用订阅包含的所有模型。

  完成登录前置条件是：可用的科学上网工具 + Anthropic 订阅账号；科学上网路由模式设置为全局模式。登录步骤如下：

  # cmd 窗口执行如下命令，打开 claude 终端
  claude
  
  # 在 claude 终端输入如下指令，根据提示完成登录即可
  /login

  登录有图中几种模式选择，订阅账号登录用第一种方式（国内 OAuth 风控很严）。第二种方式是使用 API Key ，需要去官网创建，按 Token 收费，非常昂贵。第三种用于企业，配置复杂，此处不做介绍。

  

  注意

  在登录过程中，肯定会遇到无法登录问题，网页能打开 Claude 官网，但在 Claude Code 中尝试登录，最终会提示：
  OAuth error: Request failed with status code 403
  这是因为 Claude Code 直接请求 Claude API，风控和校验规则更加严格。跟着下面步骤操作，可解决这个问题。

• VPN 代理配置

  其实，Claude Code 本质是一个 Node.js CLI 程序，在 Windows 下不会自动读取系统代理，因此需要显式指定代理，否则 OAuth/API 请求可能仍然走本地直连而导致登录失败。

  以 V2rayN 为例，在设置->参数设置中，检查一下本地监听端口（所有节点均通过此端口代理数据），如图：

  

  提示

  不同代理软件，默认本地监听端口可能不一样，v2rayN 使用的 10808，Clash 使用的 7890 等；

  在系统环境变量中，通过设置 HTTP_PROXY / HTTPS_PROXY / ALL_PROXY 环境变量（如图），显式告诉 Node.js 应该通过哪个本地代理端口访问网络就行了。一个一个去新增环境变量太痛苦了，这里提供一个 bat 脚本一键设置。

  环境变量

  

  一键设置环境变量

  @echo off
  setlocal enabledelayedexpansion
  REM 这是个设置用户环境变量的脚本，特点：相同就跳过、不同才更新、没有才新增，反复运行都安全 ！！！！
  REM 这个脚本非常通用，适用于 Windows 中任何添加用户系统变量的操作，唯一需要指定的就是环境变量的键值对
  
  REM ===================== 配置区 =====================
  REM 格式：set "MAP[变量名]=变量值"   —— 像 map 一样，键在[]里，值在=右边
  REM 新增变量：照着下面再加一行即可，无需改动其它任何地方
  set "MAP[HTTP_PROXY]=http://127.0.0.1:10808"
  set "MAP[HTTPS_PROXY]=http://127.0.0.1:10808"
  set "MAP[ALL_PROXY]=socks5://127.0.0.1:10808"
  REM ===============================================================
  
  echo 正在写入【用户】环境变量（不影响系统变量和其它已有变量）...
  echo.
  
  REM 遍历所有 MAP[...] 变量：%%K 取到 "MAP[键]"，%%L 取到值
  for /f "tokens=1,* delims==" %%K in ('set MAP[ 2^>nul') do (
      set "KEY=%%K"
      set "VALUE=%%L"
      REM 从 "MAP[键]" 中剥掉前缀 MAP[ 和后缀 ] ，得到纯键名
      set "KEY=!KEY:MAP[=!"
      set "KEY=!KEY:]=!"
      call :SetUserEnv "!KEY!" "!VALUE!"
  )
  
  echo.
  echo 完成！请关闭并重新打开终端后才会生效。
  pause
  exit /b
  
  
  REM ---------- 子程序：设置单个用户环境变量（幂等，不会重复添加）----------
  :SetUserEnv
  set "NAME=%~1"
  set "VALUE=%~2"
  set "CURRENT="
  REM 读取注册表里该变量当前的值，不存在则 CURRENT 为空
  for /f "tokens=2,* delims= " %%a in ('reg query "HKCU\Environment" /v "%NAME%" 2^>nul ^| findstr /i "%NAME%"') do set "CURRENT=%%b"
  
  if "!CURRENT!"=="%VALUE%" (
      echo [跳过] %NAME% 已存在且值相同。
  ) else (
      REM setx 不带 /M ＝ 只写入【用户】变量，且只覆盖这一个变量
      setx "%NAME%" "%VALUE%" >nul
      if "!CURRENT!"=="" (
          echo [新增] %NAME% = %VALUE%
      ) else (
          echo [更新] %NAME% : !CURRENT! -^> %VALUE%
      )
  )
  exit /b

  一键清除环境变量

  @echo off
  setlocal enabledelayedexpansion
  
  REM ===================== 配置区（以后只改这里）=====================
  REM 要移除的变量名，空格分隔；新增变量直接往后加名字即可
  set "KEYS=HTTP_PROXY HTTPS_PROXY ALL_PROXY"
  REM ===============================================================
  
  echo 正在从【用户】环境变量中移除以下变量...
  echo.
  
  for %%K in (%KEYS%) do call :DelUserEnv "%%K"
  
  echo.
  echo 完成！请关闭并重新打开终端；部分程序可能需要重新登录后才彻底生效。
  pause
  exit /b
  
  
  REM ---------- 子程序：删除单个用户环境变量（不存在则跳过）----------
  :DelUserEnv
  set "NAME=%~1"
  reg query "HKCU\Environment" /v "%NAME%" >nul 2>nul
  if errorlevel 1 (
      echo [跳过] %NAME% 本来就不存在。
  ) else (
      reg delete "HKCU\Environment" /v "%NAME%" /f >nul
      echo [删除] %NAME% 已移除。
  )
  exit /b

  环境变量设置好后，新开一个 cmd 窗口重新登录即可，若遇到问题，确保使用的 Claude Code 版本是最新版。只要登录成功一次，后续就无需登陆了，登录认证信息保存在 C:\Users\你的用户名\.claude\.credentials.json 中。